Un módulo en PowerPoint y Visual Basic
A continuación se presentan varias alternativas de procedimientos o script en visual Basic que se pueden adaptar en PowerPoint para crear un módulo interactivo. El módulo debe contener al menos las siguientes partes:
- Página de inicio
- Introducción
- Objetivos instruccionales
- Contenido (desarrollo del tema)
- Prueba de autoevaluación
- Referencias
En la página de inicio aparece el script para que el estudiante escriba su nombre. La segunda y tercera pantalla es de selección múltiple. Aunque sólo se incluyen dos ítems, puede añadir más. La cuarta pantalla es un ejemplo para escribir una información. La pregunta que hace es ¿Cuál es el nombre del perro de Orlando? La respuesta es Pipo. Fue lo que se me ocurrió en ese momento después de haberle dado comida al perro. La quinta pantalla muestra un botón para ver los resultados. Al hacer clic se genera automáticamente una sexta pantalla (lo hace el script) que presenta las respuestas que hizo el estudiante en la prueba. Además incluye un botón para que pueda imprimir los resultados. Sólo imprime esa pantalla.
También puede crear botones con el Action Bottom de PowerPoint. Este permite pasar a una página en particular, ir a la pantalla anterior, la siguiente, a la primera pantalla, salir de la presentación y otros.
Uso de Macros en PowerPoint
La siguiente actividad es complemento de la primera y consiste en preparar una prueba corta sobre la lección que hizo en Microsoft Word. Para ello, utilizará el programa Microsoft PowerPoint y la función de macro que es una programación que se hace utilizando Visual Basic for Applications (VBA).Prepara una prueba de selección múltiple de al menos cinco pantallas (slides). Cada pantalla será un reactivo. En el cual aparecerá la pregunta y las alternativas que tendrá el estudiante. Puede ser de tres o cuatro alternativas. La alternativa correcta le dará un mensaje al estudiante que leerá: ¡Correcto! Las alternativas incorrectas leerán: No es la respuesta correcta, inténtalo nuevamente. Cuando el estudiante responda adecuadamente, PowerPoint le permitirá pasar a la próxima pantalla para continuar la prueba.
Paso 1
Active el programa y seleccione un background o fondo que le guste. Asegúrese que sea adecuado para los estudiantes que atenderá (nivel de enseñanza). Luego seleccione el layout de Title Only. Este se encuentra en el lado izquierdo de la pantalla y lo puede identificar si observa que es el único que tiene una línea superior y el resto es en blanco.
Escriba la pregunta en la sección de Title. Luego haga clic en Slide Show (barra superior) y seleccione Action Buttons. Haga clic en el primer cuadro de las opciones que presenta.
Sale una ventana, haga clic en Cancel. El cursor está listo para hacer el botón. Trace un botón en la pantalla que le servirá para escribir el texto correspondiente a las alternativas de las preguntas. Una vez creado el botón, presione el botón derecho del mouse y seleccione Format AutoShape. Aparecerá una pantalla que le permitirá modificar el color del botón, entre otras opciones. Escoja un color apropiado al fondo que utilizó.
Seleccione el botón que hizo y haga copy y luego paste. Haga paste para cada alternativa. De esta manera los botones le quedarán iguales y será cuestión de alinearlos en la pantalla.
Seleccione el primer botón y presione el botón derecho del mouse. Escoja la opción Edit Tex (como se muestra en el gráfico). Escriba la respuesta. Puede aumentar el aumento del texto y cambiar el tipo de letra. Escriba las respuestas 2 y 3. Si son cuatro opciones, escriba la cuarta. Añada un último botón que servirá de final o salir de la prueba. Guarde su trabajo.
Debe quedar algo así:
Paso 2
Como ya tiene una pantalla creada, puede repetirla varias veces. Así sólo tendrá que modificar los textos. Para ello, vaya a View y seleccione Slide Sorter. Aparecerá su pantalla en cuadro pequeño. Selecciónela y déle copy y luego paste. Repita el paste hasta que tenga cinco pantallas (es el mínimo requerido para la tarea). Si su prueba es de más de cinco, continúe el paste hasta completarla.
Seleccione Tools del menú superior, escoja la opción Macro y haga clic en Visual Basic Editor y verá que aparece una ventana. Esa es la venta de Microsoft Visual Basic. Seleccione la opción Insert y escoja Module. Sale un espacio en blanco en la ventana. Consulte el siguiente enlace para más información:
http://www.education.tas.gov.au/itproject/ppt_vba/message_box.htm#
En ese espacio en blanco van las instrucciones para los botones que construyó. Tendrán un mensaje para las respuestas correctas, uno para las incorrectas y uno cuando termina la prueba. Copie las siguientes líneas de programación y colóquelas en el espacio en blanco (puede cambiar el mensaje que está entre comillas).
Sub Wrong()
MsgBox ("No es la respuesta correcta, inténtalo nuevamente.")
End Sub
Sub Right()
MsgBox ("¡Correcto!")SlideShowWindows(1).View.Next
End Sub
Sub RightLast()
MsgBox ("¡Felcidades, completaste la prueba!")
End Sub
Haga clic en el botón de Save y cierre la pantalla de Visual Basic.
Paso 3
Seleccione el primer botón de respuesta (asegúrese que selecciona el botón y no el texto). Presione el botón derecho del mouse y escoja Action Setting. Haga clic en la bolita que está frente a Run Macro.Ver video de Action Settings
Observará que tiene tres alternativas:
Right = alternativa correcta
RightLast = alternativa correcta para la última pantalla
Wrong = respuesta incorrecta
Para el botón de Salir, haga clic en él con el botón derecho del mouse. Seleccione Action Settings y escoja la opción Hyperlink y la alternativa End Show. Clic en OK. De esta manera, el estudiante podrá salir de la prueba en cualquier momento.
Finalmente, haga clic en la opción Slide Show (menú superior) y luego en Set UpShow. Presione el botón Browsed at a kiosk (full screen). Clic en OK.
Grabe su trabajo y véalo en el modo de presentación (puede presionar la tecla de función F5).
Uso de Visual Basic en PowerPoint
El Departamento de Educación de Estados Unidos, tiene una página que explica en detalle el uso de Visual Basic en PowerPoint. Incluye segmentos de video, que puede ayudarlo/a para ejecutar la tarea. Acceda la página en: http://www.education.tas.gov.au/itproject/ppt_vba/
Cuando vea el siguiente cuadro, podrá acceder a un video clip:
El siguiente script fue adaptado del libro Powerful PowerPoint for Educador: Using Visual Basic for Applications to Make PowerPoint Interactive del Dr. David M. Marcovitz. Para más información puede consultar: http://www.loyola.edu/education/PowerfulPowerPoint/MoreTricks.html
A continuación se presenta el script del proyecto completo, no obstante utilice el que mejor se adapte a su módulo. Puede copiarlo completo o por partes. El procedimiento es el mismo que se utilizó en la sección anterior de Uso de Macros en PowerPoint.
La sección Dim define las variables, por lo que se recomienda que aparezca al principio. Puede copiar todo el script, aunque no incluya algunos de ellos. Puede ver un ejemplo en PowerPoint en el siguiente documento:
Ejemplo Presentación PPT
Dim numCorrect As Integer
Dim numIncorrect As Integer
Dim userName As String
Dim q1Answered As Boolean
Dim q2Answered As Boolean
Dim q3Answered As Boolean
Dim answer1 As String
Dim Answer2 As String
Dim answer3 As String
Dim answerFile
Sub askName()
userName = InputBox(prompt:="¿Cuál es tu nombre?", _
Title:="Nombre")
MsgBox ("Hola " & userName)
Do While userName = ""
userName = InputBox(prompt:="Escribe tu nombre", _
Title:="Nombre")
Beep
Loop
ActivePresentation.SlideShowWindow.View.Next
End Sub
Sub Initialize()
numCorrect = 0
numIncorrect = 0
q1Answered = False
q2Answered = False
q3Answered = False
End Sub
Sub DoingWell()
MsgBox ("Muy bien, " & userName)
End Sub
Sub DoingPoorly()
MsgBox ("Inténtalo otra vez, " & userName)
End Sub
Sub Answer1SanJuan()
If q1Answered = False Then
numCorrect = numCorrect + 1
answer1 = "San Juan - Respuesta correcta"
End If
q1Answered = True
DoingWell
ActivePresentation.SlideShowWindow.View.Next
End Sub
Sub Answer1Ponce()
If q1Answered = False Then
numIncorrect = numIncorrect + 1
answer1 = "Ponce - Respuesta incorrecta"
End If
q1Answered = True
DoingPoorly
End Sub
Sub Answer2Existe()
If q2Answered = False Then
numCorrect = numCorrect + 1
Answer2 = "Existe diferencia - Correcto" 'ADDED
End If
q2Answered = True
DoingWell
ActivePresentation.SlideShowWindow.View.Next
End Sub
Sub Answer2Noexiste()
If q2Answered = False Then
numIncorrect = numIncorrect + 1
Answer2 = "No existe diferencia - Incorrecto"
End If
q2Answered = True
DoingPoorly
End Sub
Sub Question3()
Dim answer
answer = InputBox(prompt:="¿Cómo se llama el perro de Orlando?", _
Title:="Question 3")
If q3Answered = False Then 'ADDED
answer3 = answer 'ADDED
End If 'ADDED
answer = Trim(answer)
answer = LCase(answer)
If answer = "pipo" Then
RightAnswer3
Else
WrongAnswer3
End If
End Sub
Sub RightAnswer3()
If q3Answered = False Then
numCorrect = numCorrect + 1
End If
q3Answered = True
DoingWell
ActivePresentation.SlideShowWindow.View.Next
End Sub
Sub WrongAnswer3()
If q3Answered = False Then
numIncorrect = numIncorrect + 1
End If
q3Answered = True
DoingPoorly
End Sub
Sub PrintablePage()
Const ForReading = 1, ForWriting = 2, ForAppending = 8
Dim fs, f
Dim printableSlide As Slide
Dim homeButton As Shape
Dim printButton As Shape
Set printableSlide = ActivePresentation.Slides.Add(Index:=6, _
Layout:=ppLayoutText)
printableSlide.Shapes(1).TextFrame.TextRange.Text = _
"Resultados de " & userName
printableSlide.Shapes(2).TextFrame.TextRange.Text = _
"Respuestas" & Chr$(13) & _
"Pregunta 1: " & answer1 & Chr$(13) & _
"Pregunta 2: " & Answer2 & Chr$(13) & _
"Pregunta 3: " & answer3 & Chr$(13) & _
"Obtuviste " & numCorrect & " de " & _
numCorrect + numIncorrect & "." & Chr$(13) & _
"Si presionas el botón Imprimir te puedes llevar los resultados"
Set printButton = ActivePresentation.Slides(6).Shapes.AddShape _
(msoShapeActionButtonCustom, 600, 50, 100, 50)
printButton.TextFrame.TextRange.Text = "Imprimir"
printButton.ActionSettings(ppMouseClick).Action = ppActionRunMacro
printButton.ActionSettings(ppMouseClick).Run = "PrintResults"
ActivePresentation.SlideShowWindow.View.Next
ActivePresentation.Saved = True
End Sub
Sub PrintResults()
ActivePresentation.PrintOptions.OutputType = ppPrintOutputSlides
ActivePresentation.PrintOut From:=6, To:=6
End Sub